工程人員您們好:
1.請問若今日股價跳空,要以前一日之收盤價為支撐,向右劃一水平支撐線,並寫上價位,公式該如何寫(顯示於Ｋ線主圖上)?
2.若要已K>50(K由下往上穿越)當天之K線高點為壓力,向右劃一水平壓力線,並寫上價位,公式該如何寫(顯示於Ｋ線主圖上)?

謝謝回覆

努力了一天，發覺要設定跳空的語法不好表現。

一休學長忙﹐我試了一下﹐不知道是不是這個樣子.......
(沒有標上價位﹐不過....滑鼠移過去會自動顯示價位！)



公式：
{KD公式 Begin}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1),LineThick0,ColorWhite;
D:=SMA(K,3,1),LineThick0,ColorWhite;
{KD公式 End}
{*************以下為跳空劃線K棒標示***********}
B1:= LOW > REF(High,1);
B1T:=BarsLast(B1);
CC:=Ref(Close,B1T+1);
跳空支撐:CC,LineThick0,ColorRed;
PartLine(B1<>1,CC),ColorRed;
{*************以下為 K大於50 劃線K棒標示***********}
KC50 := Cross(K,50);
KC50T := BarsLast(KC50);
K50壓力:Ref(High,Ref(KC50T,1)+1),LineThick0,ColorWhite;
DrawLine(KC50,High,KC50,K50壓力,0),ColorWhite;

感謝一休兄及yes6689兄的回覆
正是我所需要的

感謝yes6689兄的分享，這也正是0152533兄需要
的，太好了。

我試著將價位貼上,不知位置對不對? 請指導
B1:= LOW > REF(High,1);
B1T:=BarsLast(B1);
CC:=Ref(Close,B1T+1);
跳空支撐點:CC,LineThick0,COLORYELLOW;
PartLine(B1<>1,CC),COLORYELLOW;
DrawNumber(b1=1,cc,cc,1),align2,COLORYELLOW;

P0178兄使用五彩K線輔助檢測此撰寫方式可行,感謝您的服務

請問如果只要劃缺口發生後的N個棒線，要如何寫？

把這個CC:=Ref(Close,B1T+1);
內B1T+1 =>用n取代即可

n為常數
input n=1,1,99
可任意調用

大家討論交流的感覺............真是好！！

請問想要在每個波的峰頂的最高價及谷底的最低價各劃一條線,公式函數要如何寫?

參數名
P1(5,1,60)
ZX:ZIG(CLOSE,P1);
Var1:=FLATZIG(C,P1);
Var2:=Var1=0;
DRAWNUMBER(Var1,H,H,2),ALIGN2;
DRAWNUMBER(Var2,L,L,2),ALIGN2;
內行人因當了解這函數在實務定義上僅供參考,找不到真實點
如果要找到真實點必需寫一長串的程式碼來重新定義,先寫到這邊因為我又沒靈感,我寫程式是很隨興的

這樣已解決找線的困擾,不足之處只好目測,但若有哪位仁兄願意再突破當感激不進,
奇狐論壇真是一處寶地

您好:
轉貼飛狐大陸技術顧問清揚老師的作品,看是否符合需求
參數可自行更改,N越小波浪越細

A1:=REF(H,N)=HHV(H,2*N+1);
B1:=FILTER(A1,N);
C1:=BACKSET(B1,N+1);
D1:=FILTER(C1,N);

A2:=REF(L,N)=LLV(L,2*N+1);
B2:=FILTER(A2,N);
C2:=BACKSET(B2,N+1);
D2:=FILTER(C2,N);

E1:=(REF(LLV(L,2*N),1)+REF(HHV(H,2*N),1))/2;
E2:=(H+L)/2;

H1:=(D1 AND NOT(D2 AND E1>=E2)) OR ISLASTBAR OR BARSCOUNT(C)=1;
L1:=(D2 AND NOT(D1 AND E1<E2));
H2:=D1 AND NOT(D2 AND E1>=E2);
X1:=REF(BARSLAST(H1),1)+1; F1:=BACKSET(H1 AND COUNT(L1,X1)>0,LLVBARS(IF(L1,L,10000),X1));
G1:=F1>REF(F1,1); I1:=BACKSET(G1,2); LD:=I1>REF(I1,1);

L2:=LD OR ISLASTBAR OR BARSCOUNT(C)=1;
X2:=REF(BARSLAST(L2),1)+1;
F2:=BACKSET(L2 AND COUNT(H2,X2)>0,HHVBARS(IF(H2,H,0),X2));
G2:=F2>REF(F2,1); I2:=BACKSET(G2,2); HD:=I2>REF(I2,1);

UL:=IF(REF(HD,N)=1 AND SUM(HD,N-1)=0,REF(H,N),REF(H,N+BARSLAST(REF(HD,N)=1 AND SUM(HD,N-1)=0)));
DL:=IF(REF(LD,N)=1 AND SUM(LD,N-1)=0,REF(L,N),REF(L,N+BARSLAST(REF(LD,N)=1 AND SUM(LD,N-1)=0)));

JHH:=H>UL AND REF(H,1)<=REF(UL,1) AND SUM(H>UL AND REF(H,1)<=REF(UL,1),BARSLAST(HD))=1;
JLL:=L<DL AND REF(L,1)>=REF(DL,1) AND SUM(L<DL AND REF(L,1)>=REF(DL,1),BARSLAST(HD))=1;

DRAWICON(JHH,H,4),ALIGN0;
DRAWICON(JLL,L,5);
DRAWLINE(LD,L,HD,H,0),COLORGREEN,POINTDOT;
DRAWLINE(HD,H,LD,L,0),COLORGREEN,POINTDOT;

SX1:=BACKSET(ISLASTBAR,BARSLAST(LD)+1);
SX2:=SX1>REF(SX1,1);
SY1:=BACKSET(ISLASTBAR,BARSLAST(HD)+1);
SY2:=SY1>REF(SY1,1);
SZ1:=IF(BARSLAST(SX2)<BARSLAST(SY2),SX2,SY2);
SZ2:=IF(BARSLAST(SX2)<BARSLAST(SY2),L,H);
DRAWLINE(SZ1,SZ2,ISLASTBAR,C,0),COLORBLUE,POINTDOT;

DRAWNUMBER(HD,H*(1+sk),H,2),COLORGREEN,align0;
DRAWNUMBER(LD,L*(1.001-sk),L,2),COLORGREEN,align0;

最近１次碎型高:IF(HD,H,REF(H,BARSLAST(HD))),LINETHICK0;
最近１次碎型低:IF(LD,L,REF(L,BARSLAST(LD))),LINETHICK0;

0152533兄
感謝謝您的轉貼,原碼我也有,但尚未去函獲得清揚兄的授權所以一直未貼出來,您貼出來那我必需寫一份正式文件照會清揚兄了,算是尊重原創作者,這樣別人以後才會樂於發表,必盡網路世界目前發展的進度與真實世界密切度越來越真實了