|
jiat
資深會員
註冊日期: Apr 2004
來 自:
文章數量: 119 |
绝品公式-新结构波浪
绝品公式-新结构波浪!(本公式为清杨大侠的绝品之作)
说明:本公式为清杨大侠的绝品之作,在此谢谢清杨大侠!最早看到这个公式是在某股票论坛,有人贴此公式的贴图,卖弄之余,且不肯拿出示人!清杨兄作此公式,且公开源码,决不是给这些小人卖弄牟利的,如此更有违清杨大侠的本意!纵横股海,又企是拥有一两个极品公式所能做到的!心胸狭窄的人永远成不了股海的赢家!
这个公式最好用作主图指标,判断股价运行趋势!喜欢的朋友帮我顶呀!举手之劳,在此谢过!
{以下语句为新结构波浪}
A1:=REF(HIGH,3)=HHV(HIGH,2*3+1); B1:=FILTER(A1,3); C1:=BACKSET(B1,3+1); D1:=FILTER(C1,3);{高点}
A2:=REF(LOW,3)=LLV(LOW,2*3+1); B2:=FILTER(A2,3); C2:=BACKSET(B2,3+1); D2:=FILTER(C2,3);{低点}
E1:=(REF(LLV(LOW,2*3),1)+REF(HHV(HIGH,2*3),1))/2; E2:=(HIGH+LOW)/2;{高低点出现在同一K线上时可作取舍}
H1:=(D1 AND NOT(D2 AND E1>=E2)) OR ISLASTBAR OR BARSCOUNT(CLOSE)=1;
L1:=(D2 AND NOT(D1 AND E1<E2)); H2:=D1 AND NOT(D2 AND E1>=E2);
X1:=REF(BARSLAST(H1),1)+1; F1:=BACKSET(H1 AND COUNT(L1,X1)>0,LLVBARS(IF(L1,LOW,10000),X1));
G1:=F1>REF(F1,1); I1:=BACKSET(G1,2); LD:=I1>REF(I1,1);{过滤后低点}
L2:=LD OR ISLASTBAR OR BARSCOUNT(CLOSE)=1;
X2:=REF(BARSLAST(L2),1)+1; F2:=BACKSET(L2 AND COUNT(H2,X2)>0,HHVBARS(IF(H2,HIGH,0),X2));
G2:=F2>REF(F2,1); I2:=BACKSET(G2,2); HD:=I2>REF(I2,1);{过滤后高点}
DRAWLINE(LD,L,HD,H,0),COLORWHITE,LINETHICK1,POINTDOT;
DRAWLINE(HD,H,LD,L,0),COLORWHITE,LINETHICK1,POINTDOT;
J1:=BACKSET(ISLASTBAR,MIN(BARSLAST(HD),BARSLAST(LD))+1); J2:=J1>REF(J1,1);
DRAWLINE(J2,IF(HD,H,L),ISLASTBAR,IF(BARSLAST(HD)>BARSLAST(LD),H,L),0),COLORWHITE,LINETHICK1,POINTDOT;
{以上语句为新结构波浪}
A3:=H<REF(H,REF(BARSLAST(HD),1)+1);
B3:=REF(H,REF(BARSLAST(HD),1)+1)>REF(H,REF(BARSLAST(HD),1)+2+REF(BARSLAST(HD),REF(BARSLAST(HD),1)+2));
D3:=A3 AND B3 AND HD; E3:=BACKSET(D3,REF(BARSLAST(HD),1)+2); HH:=E3>REF(E3,1);{找出全部长期高点}
A4:=L>REF(L,REF(BARSLAST(LD),1)+1);
B4:=REF(L,REF(BARSLAST(LD),1)+1)<REF(L,REF(BARSLAST(LD),1)+2+REF(BARSLAST(LD),REF(BARSLAST(LD),1)+2));
D4:=A4 AND B4 AND LD; E4:=BACKSET(D4,REF(BARSLAST(LD),1)+2); LL:=E4>REF(E4,1);{找出全部长期低点}
DRAWICON(HH,H,10),ALIGN2; DRAWICON(LL,L,12),ALIGN1;
H3:=HH OR ISLASTBAR OR BARSCOUNT(C)=1; {后面进行过滤,方法同前。只是不用考虑高低点出现在同一K线}
X3:=REF(BARSLAST(H3),1)+1; F3:=BACKSET(H3 AND COUNT(LL,X3)>0,LLVBARS(IF(LL,L,POW(10,20)),X3));
G3:=F3>REF(F3,1); I3:=BACKSET(G3,2); LZ:=I3>REF(I3,1),LINETHICK0; {长期低点,也可供引用}
L4:=LZ OR ISLASTBAR OR BARSCOUNT(C)=1;
X4:=REF(BARSLAST(L4),1)+1; F4:=BACKSET(L4 AND COUNT(HH,X4)>0,HHVBARS(IF(HH,H,-POW(10,20)),X4));
G4:=F4>REF(F4,1); I4:=BACKSET(G4,2); HZ:=I4>REF(I4,1),LINETHICK0;{长期高点,也可供引用}
DRAWLINE(HZ,H,LZ,L,0),COLORGREEN,LINETHICK1;
DRAWLINE(LZ,L,HZ,H,0),COLORGREEN,LINETHICK1;{长期连线}
K1:=BACKSET(ISLASTBAR,MIN(BARSLAST(HZ),BARSLAST(LZ))+1); K2:=K1>REF(K1,1);
DRAWLINE(K2,IF(HZ,H,L),ISLASTBAR,C,0),COLORGREEN,LINETHICK1; {最后的长期连线,连在收盘价上}
{以下是两条趋势线原码}
UU:=BACKSET(ISLASTBAR,BARSLAST(LD)+1);
VV:=UU>REF(UU,1);
WW:=BACKSET(VV,REF(BARSLAST(LD),1)+2);
XX:=WW>REF(WW,1);
DRAWLINE(XX,L,VV,L,1),COLORMAGENTA,LINETHICK1;
UU2:=BACKSET(ISLASTBAR,BARSLAST(HD)+1);
VV2:=UU2>REF(UU2,1);
WW2:=BACKSET(VV2,REF(BARSLAST(HD),1)+2);
XX2:=WW2>REF(WW2,1);
DRAWLINE(XX2,H,VV2,H,1),COLORMAGENTA,LINETHICK1;
前一低:REF(L,BARSLAST(VV)),COLOR99FF66,POINTDOT,LINETHICK3;
前二低:REF(L,BARSLAST(XX)),COLORFF66FF,POINTDOT,LINETHICK3;
前一高:REF(H,BARSLAST(VV2)),COLOR99FF66,POINTDOT,LINETHICK3;
前二高:REF(H,BARSLAST(XX2)),COLORFF66FF,POINTDOT,LINETHICK3;
短高:=REF(H,BARSLAST(VV2)),LINETHICK0;
短低:=REF(L,BARSLAST(VV)),LINETHICK0;
短比: (C-短低)/(短高-短低),LINETHICK0;
{以下语句是大盘趋势叠加}
常数:=REF(INDEXC,BARSLAST(VV))/REF(C,BARSLAST(VV));
叠1:INDEXC/常数,COLORGRAY,LINETHICK0;
PARTLINE(1,叠1),COLORGRAY;
常数2:=REF(INDEXC,BARSLAST(XX))/REF(C,BARSLAST(XX));
叠2:INDEXC/常数2,COLORGRAY,LINETHICK0;
PARTLINE(1,叠2),COLORGRAY;
DRAWNUMBER(HD,1.02*H,DATEDIFF(REF(DATE,BARSLAST(LD)),DATE),0),COLORCYAN;
DRAWNUMBER(LD,0.98*L,DATEDIFF(REF(DATE,BARSLAST(HD)),DATE),0),COLORCYAN;
DRAWNUMBER(HD,H*(1+0.002),H,2),COLORBLUE,ALIGN0;
DRAWNUMBER(LD,L*(1.001-0.002),L,2),COLORBLUE,ALIGN0;
|
|
向版主報告此篇 | |
|
2004-09-09 01:12 |
|
|
| |
|
| |
|
九尾妖狐
中級會員
註冊日期: Aug 2004
來 自:
文章數量: 92 |
波浪公式..清晰版
讓大家看的更清楚
附件: out.ALG
此文件已被下載 1104 次。
__________________
成功只有一條路那就是不斷的努力..試了失敗就要一試再試..當你不再去試..才是真正的失敗..
|
|
向版主報告此篇 | |
|
2004-09-09 15:08 |
|
|
| |
|
九尾妖狐
中級會員
註冊日期: Aug 2004
來 自:
文章數量: 92 |
圖檔
九尾妖狐 附帶上了此圖片:
__________________
成功只有一條路那就是不斷的努力..試了失敗就要一試再試..當你不再去試..才是真正的失敗..
|
|
向版主報告此篇 | |
|
2004-09-09 15:10 |
|
|
| |
|
九尾妖狐
中級會員
註冊日期: Aug 2004
來 自:
文章數量: 92 |
有阿妳的沒顯示喔...應該是不會阿..每個週期應該都能用
九尾妖狐 附帶上了此圖片:
__________________
成功只有一條路那就是不斷的努力..試了失敗就要一試再試..當你不再去試..才是真正的失敗..
|
|
向版主報告此篇 | |
|
2004-09-10 10:05 |
|
|
| |
|
九尾妖狐
中級會員
註冊日期: Aug 2004
來 自:
文章數量: 92 |
試試看這種的..應該是沒問題才對
附件: out.ALG
此文件已被下載 866 次。
__________________
成功只有一條路那就是不斷的努力..試了失敗就要一試再試..當你不再去試..才是真正的失敗..
|
|
向版主報告此篇 | |
|
2004-09-10 13:43 |
|
|
| |
|
九尾妖狐
中級會員
註冊日期: Aug 2004
來 自:
文章數量: 92 |
圖檔
九尾妖狐 附帶上了此圖片:
__________________
成功只有一條路那就是不斷的努力..試了失敗就要一試再試..當你不再去試..才是真正的失敗..
|
|
向版主報告此篇 | |
|
2004-09-10 13:44 |
|
|
| |
|
jiat
資深會員
註冊日期: Apr 2004
來 自:
文章數量: 119 |
AA:=REF(H,N1)=HHV(H,2*N1+1);
AAA:=FILTER(AA,N1);
BB:=BACKSET(AAA,N1+1);
CC1:=FILTER(BB,N1);
CC:=CC1 OR ISLASTBAR;
AA2:=REF(L,N1)=LLV(L,2*N1+1);
AAA2:=FILTER(AA2,N1);
BB2:=BACKSET(AAA2,N1+1);
CC22:=FILTER(BB2,N1);
CC2:=CC22 AND NOT(CC1);
EA:=BACKSET(CC,REF(BARSLAST(CC2),1)+1);
EB:=EA>REF(EA,1); EE:=BACKSET(EB,2);
FF1:=EE>REF(EE,1);
EE2:=BACKSET(FF1 AND COUNT(CC,REF(BARSLAST(CC2),1)+2)=0,REF(BARSLAST(CC2),1)+2);
FF2:=EE2>REF(EE2,1);
EE3:=BACKSET(FF2 AND COUNT(CC,REF(BARSLAST(CC2),1)+2)=0,REF(BARSLAST(CC2),1)+2);
FF3:=EE3>REF(EE3,1);
JS:=IF(CC,COUNT(CC2,REF(BARSLAST(CC),1)+1),0);
G1:=IF(JS=1 AND CC,BARSLAST(FF1),0);
GA:=IF(CC AND REF(L,BARSLAST(FF1))>=REF(L,BARSLAST(FF2)),BARSLAST(FF2),BARSLAST(FF1));
G2:=IF(JS=2 AND CC,GA,0);
G3:=IF(JS>=3 AND CC,IF(CC AND REF(L,GA)>=REF(L,BARSLAST(FF3)),BARSLAST(FF3),GA),0);
GG:=G1+G2+G3;
JA:=BACKSET(CC,GG); JB:=JA>REF(JA,1); JJ:=BACKSET(JB,2);
LD:=JJ>REF(JJ,1);
LD1:=LD OR ISLASTBAR;
hEA:=BACKSET(LD1,REF(BARSLAST(CC),1)+1);
hEB:=hEA>REF(hEA,1); hEE:=BACKSET(hEB,2);
hFF1:=hEE>REF(hEE,1);
hEE2:=BACKSET(hFF1 AND COUNT(LD1,REF(BARSLAST(CC),1)+2)=0,REF(BARSLAST(CC),1)+2);
hFF2:=hEE2>REF(hEE2,1);
hEE3:=BACKSET(hFF2 AND COUNT(LD1,REF(BARSLAST(CC),1)+2)=0,REF(BARSLAST(CC),1)+2);
hFF3:=hEE3>REF(hEE3,1);
hJS:=IF(LD1,COUNT(CC1,REF(BARSLAST(LD1),1)+1),0);
hG1:=IF(hJS=1 AND LD1,BARSLAST(hFF1),0);
hGA:=IF(LD1 AND REF(H,BARSLAST(hFF1))<=REF(H,BARSLAST(hFF2)),BARSLAST(hFF2),BARSLAST(hFF1));
hG2:=IF(hJS=2 AND LD1,hGA,0);
hG3:=IF(hJS>=3 AND LD1,IF(LD1 AND REF(H,hGA)<=REF(H,BARSLAST(hFF3)),BARSLAST(hFF3),hGA),0);
hGG:=hG1+hG2+hG3;
hJA:=BACKSET(LD1,hGG); hJB:=hJA>REF(hJA,1); hJJ:=BACKSET(hJB,2);
HH:=hJJ>REF(hJJ,1);
{
DRAWICON(HD,H*1.01,10);
DRAWICON(LD,L*0.995,11);
}
DRAWLINE(LD,L,HH,H,0),COLORBLUE,LINETHICK2;
DRAWLINE(HH,H,LD,L,0),COLORBLUE,LINETHICK2;
X1:=BACKSET(ISLASTBAR,BARSLAST(LD)+1);
X2:=X1>REF(X1,1);
Y1:=BACKSET(ISLASTBAR,BARSLAST(HH)+1);
Y2:=Y1>REF(Y1,1);
Z1:=IF(BARSLAST(X2)<BARSLAST(Y2),X2,Y2);
Z2:=IF(BARSLAST(X2)<BARSLAST(Y2),L,H);
DRAWLINE(Z1,Z2,ISLASTBAR,C,0),COLORGREEN,LINETHICK2;
UU:=BACKSET(ISLASTBAR,BARSLAST(LD)+1);
VV:=UU>REF(UU,1);
WW:=BACKSET(VV,REF(BARSLAST(LD),1)+2);
XX:=WW>REF(WW,1);
DRAWLINE(XX,L,VV,L,1),COLORBLUE;
UU2:=BACKSET(ISLASTBAR,BARSLAST(HH)+1);
VV2:=UU2>REF(UU2,1);
WW2:=BACKSET(VV2,REF(BARSLAST(HH),1)+2);
XX2:=WW2>REF(WW2,1);
DRAWLINE(XX2,H,VV2,H,1),COLORBLUE;
前一低:REF(L,BARSLAST(VV)),COLOR99FF66,POINTDOT,LINETHICK4;
前二低:REF(L,BARSLAST(XX)),COLORFF66FF,POINTDOT,LINETHICK3;
前一高:REF(H,BARSLAST(VV2)),COLOR99FF66,POINTDOT,LINETHICK4;
前二高:REF(H,BARSLAST(XX2)),COLORFF66FF,POINTDOT,LINETHICK3;
短高:=REF(H,BARSLAST(VV2)),LINETHICK1;
短低:=REF(L,BARSLAST(VV)),LINETHICK1;
短比:(C-短低)/(短高-短低),LINETHICK0;
DRAWICON(CROSS(ZIG(3,10),REF(ZIG(3,10),1)),LOW*0.98,1);
DRAWICON(CROSS(REF(ZIG(3,10),1),ZIG(3,10)),HIGH*1.02,2);
;{立体K线====}
STICKLINE(c>o ,H,L,0.5,0)colorred;{上涨红}
STICKLINE(c=o and c>=ref(c,1),H,L,0.5,0)colorred;
STICKLINE(C>o,c,o,9,0),COLOR0000bb;
STICKLINE(C>o,c,o,7,0),COLOR0000cc;
STICKLINE(C>o,c,o,5,0),COLOR0011dd;
STICKLINE(C>o,c,o,3,0),COLOR0022ee;
STICKLINE(C>o,c,o,1,0),COLOR0033FF;
STICKLINE(C=o and c>=ref(c,1),c,o,8,0),COLOR0000bb;
STICKLINE(C=o and c>=ref(c,1),c,o,7,0),COLOR0000cc;
STICKLINE(C=o and c>=ref(c,1),c,o,5,0),COLOR0011dd;
STICKLINE(C=o and c>=ref(c,1),c,o,3,0),COLOR0022ee;
STICKLINE(C=o and c>=ref(c,1),c,o,1,0),COLOR0033FF;
STICKLINE(c<o,H,L,0.5,0)coloreeeeee;{下跌白}
STICKLINE(c=o and c<ref(c,1),H,L,0.5,0)coloreeeeee;
STICKLINE(o>c ,c,o,9,0 ),COLORbbbbbb;
STICKLINE(o>c ,c,o,7,0 ),COLORcccccc;
STICKLINE(o>c,c,o,5,0 ),COLORdddddd;
STICKLINE(o>c ,c,o,3,0 ),COLOReeeeee;
STICKLINE(o>c ,c,o,1,0 ),COLORffffff;
STICKLINE(o=c and c<ref(c,1),c,o,8,0 ),COLORbbbbbb;
STICKLINE(o=c and c<ref(c,1),c,o,7,0 ),COLORcccccc;
STICKLINE(o=c and c<ref(c,1),c,o,5,0 ),COLORdddddd;
STICKLINE(o=c and c<ref(c,1) ,c,o,3,0 ),COLOReeeeee;
STICKLINE(o=c and c<ref(c,1) ,c,o,1,0 ),COLORffffff;
{Simple Moving Average , MA , 简单移动平均线}
MA5:MA(CLOSE,P5),COLORBLUE,LINETHICK2;
MA4:MA(CLOSE,P3),COLORGREEN,LINETHICK2;
MA3:MA(CLOSE,P4),COLORMAGENTA,LINETHICK2;
MA1:MA(CLOSE,P1),COLORYELLOW,LINETHICK2;
MA2:MA(CLOSE,P2),COLORCYAN,LINETHICK2;
n 1 3.1.99
m 1.0.60
p 3.1.300
p2 5. 1. 300
p3 36 1 300
p4 13.1.300
p5 65.1.300
|
|
向版主報告此篇 | |
|
2004-09-10 14:35 |
|
|
| |
本站所有內容未經作者授權禁止轉貼節錄, 發表言論僅供參考勿作為投資決策依據。瀏覽本站請使用 IE 5.5 以上版本, 最佳瀏覽解析度 1024 x 768 全彩。
|
Powered by: vBulletin Version 2.3.0 - Copyright©2000-, Jelsoft Enterprises Limited.
簡愛洋行 製作 Copyright 2003-. All Rights Reserved. 聯絡我們
|