奇狐社區論壇
在這個頁面顯示本主題全部的 36 個文章

奇狐社區論壇 (http://www.chiefox.com.tw/bbs/index.php)
- 問題交流 (http://www.chiefox.com.tw/bbs/forumdisplay.php?forumid=28)
-- 請教語法[交易範例] (http://www.chiefox.com.tw/bbs/showthread.php?threadid=12898)

由 hwyhon 在 2010-01-13 06:08 發表:

請教語法

金叉:=0;
金叉:金叉;//可以顯示底下的輸出值

d:ref(金叉,BARSLAST(金叉));但此行卻出現操作類型錯誤
//**我在不使用新語法打回圈的情況下有何方法於程式頂端取得底下的值並利用作為運算**
//例如 d

A:=ma(c,10);
b:=ma(c,30);
金叉:=CROSS(A,b);

//如何將金叉丟到程式頂端方便加以再次利用

由 cgjj 在 2010-01-13 09:21 發表:

回覆: 請教語法

引用:
最初由 hwyhon 發表
金叉:=0;
金叉:金叉;//可以顯示底下的輸出值

d:ref(金叉,BARSLAST(金叉));但此行卻出現操作類型錯誤
//**我在不使用新語法打回圈的情況下有何方法於程式頂端取得底下的值並利用作為運算**
//例如 d

A:=ma(c,10);
b:=ma(c,30);
金叉:=CROSS(A,b);

//如何將金叉丟到程式頂端方便加以再次利用


金叉:=0;
金叉:金叉;
d:ref(金叉,BARSLAST(金叉)); //此行會出現操作類型錯誤
會出現操作類型錯誤的原因
是因為此刻金叉為單值, 並非數列
單值是無法計算 BARSLAST 的

Re:有何方法於程式頂端取得底下的值並利用作為運算
程式是由上到下執行的
可否說明一下需求想法和目的, 不是很懂您意思

由 hwyhon 在 2010-01-13 14:43 發表:

//例如我得知金叉成立後才要開始尋找B反轉向上進場//以之前小於進場點的那個B反轉向上A<ref(A,1) and A<refx(A,1)之直為停損出場或A反轉向下或死叉出場
//若先得取得換算後的金叉才來開始尋找B反轉向上點一些程式碼可精簡許多
//則類似此情況若沒沒得知金叉已成立否則須一回接一回程式則會寫得很囉唆
//因此才有此一問
A:ma(c,10),COLORWHITE;
B:ma(c,30),COLORGREEN;
D:ma(c,60),COLORMAGENTA;
金叉:CROSS(B,D);
VERTLINE(金叉),COLORRED,LINEDOT;
死叉:CROSS(D,B);
VERTLINE(死叉),COLORWHITE,LINEDOT;

__________________

就是發蓊梨(ㄛㄥˇ ㄌㄞˊ) 程式交易網站
[教學]指標公式及程式交易系統撰寫 [代工]

學會指標策略程式化的撰寫,將可讓你不再盲目投下辛苦賺來的血汗錢
要知道交易的策略或交易的模式長期執行下確實可獲利
交易才有意義的.否則寧可不交易


由 cgjj 在 2010-01-13 17:04 發表:

引用:
最初由 hwyhon 發表
//例如我得知金叉成立後才要開始尋找B反轉向上進場//以之前小於進場點的那個B反轉向上A<ref(A,1) and A<refx(A,1)之直為停損出場或A反轉向下或死叉出場
//若先得取得換算後的金叉才來開始尋找B反轉向上點一些程式碼可精簡許多
//則類似此情況若沒沒得知金叉已成立否則須一回接一回程式則會寫得很囉唆
//因此才有此一問
A:ma(c,10),COLORWHITE;
B:ma(c,30),COLORGREEN;
D:ma(c,60),COLORMAGENTA;
金叉:CROSS(B,D);
VERTLINE(金叉),COLORRED,LINEDOT;
死叉:CROSS(D,B);
VERTLINE(死叉),COLORWHITE,LINEDOT;


可否麻煩您以圖舉例說明呢?
這樣較易明瞭

由 hwyhon 在 2010-01-13 20:42 發表:

抱歉等會重帖

由 hwyhon 在 2010-01-13 21:01 發表:

,,,,,,,,,,,,,,,,,,,,,,,

由 hwyhon 在 2010-01-13 23:38 發表:

總算劃妥了

A:ma(c,10),COLORWHITE;
B:ma(c,30),COLORGREEN;
D:ma(c,60),COLORMAGENTA;
金叉:CROSS(B,D);
VERTLINE(金叉),COLORRED,LINEDOT;
死叉:CROSS(D,B);
VERTLINE(死叉),COLORWHITE,LINEDOT;

如貼圖

//例如我得知金叉成立後才要開始尋找B反轉向上進場及確定停損值
//以之前小於進場點的那個A均反轉向上A<ref(A,1) and A<refx(A,1)之直為停損L觸價出場
//或A反轉向下(未獲利20點不成立)出場
//或死叉出場

//若程式頂端先取得換算後的金叉才來開始尋找B反轉向上點程式碼可精簡許多
//若沒能得知金叉已成立則一些類似此情況的其它條件程式碼則會寫得很囉唆
//因此才有此一問

由 cgjj 在 2010-01-14 01:46 發表:

引用:
最初由 hwyhon 發表
總算劃妥了

A:ma(c,10),COLORWHITE;
B:ma(c,30),COLORGREEN;
D:ma(c,60),COLORMAGENTA;
金叉:CROSS(B,D);
VERTLINE(金叉),COLORRED,LINEDOT;
死叉:CROSS(D,B);
VERTLINE(死叉),COLORWHITE,LINEDOT;

如貼圖

//例如我得知金叉成立後才要開始尋找B反轉向上進場及確定停損值
//以之前小於進場點的那個A均反轉向上A<ref(A,1) and A<refx(A,1)之直為停損L觸價出場
//或A反轉向下(未獲利20點不成立)出場
//或死叉出場

//若程式頂端先取得換算後的金叉才來開始尋找B反轉向上點程式碼可精簡許多
//若沒能得知金叉已成立則一些類似此情況的其它條件程式碼則會寫得很囉唆
//因此才有此一問


處理示範如下:
原碼:


A:ma(c,10),COLORWHITE;

B:ma(c,30),COLORGREEN;

D:ma(c,60),COLORMAGENTA;

金叉:CROSS(B,D) or barpos=0 linethick0 colorred;

VERTLINE(金叉),COLORRED,LINEDOT;

死叉:CROSS(D,B) or barpos=0 linethick0 COLORWHITE;

VERTLINE(死叉),COLORWHITE,LINEDOT;



//進訊和出訊處理

前叉:=金叉-死叉 linethick0;

前叉:=ref(前叉,barslast(前叉<>0));

B上揚:=B>ref(B,1) and ref(B<ref(B,1),1);

A上揚:=A>ref(A,1) and ref(A<ref(A,1),1);

A下彎:=A<ref(A,1) and ref(A>ref(A,1),1);

金叉SP:=barslast(金叉);

進訊:=B上揚 and 前叉=1 or barpos=0;

進訊SP:=barslast(進訊<>0);

進價:=ref(C,進訊SP);

出訊:=A下彎 and C-進價>20 and sum(進訊,金叉SP+1)>0 and 前叉=1 or 死叉 or barpos=0;



//過濾連續進和連續出

CK:=進訊-出訊;

CK:=ref(CK,barslast(CK<>0));

CK:=if(CK<>ref(CK,1) or barpos=lbound(CK),CK,0);

進訊:=CK=1;

出訊:=CK=-1;



//停損處理

前訊:=進訊-出訊;

前訊SP:=barslast(前訊<>0);

前訊:=ref(前訊,前訊SP);

處SP:=ref(barslast(金叉 or 出訊 or 進訊),1)+1;

判價:=SETVAL(進訊,進價,-處SP,進價);

CKSP:=barslast(A上揚 and L<判價);

停損訊:=前訊=1 and 進訊=0 and CKSP<=處SP or barpos=0;



//濾除連續停損

停損訊:=前訊=1 and sum(停損訊,前訊SP+1)=1 or barpos=0;



//輸出訊號

DRAWICON(進訊,L,4) pxdn20;

DRAWICON(出訊,H,5) pxup45;

DRAWICON(停損訊,H,12) pxup45;

//關鍵字:多空交易範例

由 hwyhon 在 2010-01-14 09:58 發表:

訊號的完成每人的處理方式都不一
但程式判斷的精簡是關係速度的快與慢
版主的信號處理方式真是佩服
若能將新語法再做個範例
更是狐友之福阿

此題感謝版主詳細的陳述作法

感恩

由 hwyhon 在 2010-01-15 12:09 發表:

樓上經思索後發覺似乎與我真正想要的狀況有點不達意
我想這樣表達較貼切
金叉成立開始尋多
見紅棒進場停損設此紅棒的低
見黑棒若賺20點以上則出場否則等觸停損出或死叉出
出場後若見紅棒則再進場出場條件則相同一值反複至死叉止

老是麻煩版主真不好意思


A:ma(c,30),COLORGREEN;
B:ma(c,60),COLORMAGENTA;
金叉:=CROSS(A,B) or barpos=0 linethick0 colorred;
VERTLINE(金叉),COLORRED;
死叉:=CROSS(B,A) or barpos=0 linethick0 COLORWHITE;
VERTLINE(死叉),COLORWHITE;

由 cgjj 在 2010-01-15 17:35 發表:

引用:
最初由 hwyhon 發表
樓上經思索後發覺似乎與我真正想要的狀況有點不達意
我想這樣表達較貼切
金叉成立開始尋多
見紅棒進場停損設此紅棒的低
見黑棒若賺20點以上則出場否則等觸停損出或死叉出
出場後若見紅棒則再進場出場條件則相同一值反複至死叉止

老是麻煩版主真不好意思


A:ma(c,30),COLORGREEN;
B:ma(c,60),COLORMAGENTA;
金叉:=CROSS(A,B) or barpos=0 linethick0 colorred;
VERTLINE(金叉),COLORRED;
死叉:=CROSS(B,A) or barpos=0 linethick0 COLORWHITE;
VERTLINE(死叉),COLORWHITE; 


原碼:


A:ma(c,30),COLORGREEN;

B:ma(c,60),COLORMAGENTA;

金叉:=CROSS(A,B) or barpos=0 linethick0 colorred;

VERTLINE(金叉),COLORRED;

死叉:=CROSS(B,A) or barpos=0 linethick0 COLORWHITE;

VERTLINE(死叉),COLORWHITE;



//進出處理

前叉:=金叉-死叉;

前叉:=ref(前叉,barslast(前叉<>0));

進訊:=前叉*0; 出訊:=進訊; 停損訊:=進訊;

紅K:=C>O; 黑K:=C<O;

持倉:=0; 進場價:=0; 停損價:=0; CC:=C; LL:=L;

for i=lbound(前叉) to datacount do begin  

  if 紅K[i] and 前叉[i]=1 and 持倉=0 then begin

    持倉:=1;  進訊[i]:=1; 進場價:=CC[i]; 停損價:=LL[i];

  end else if 持倉=1 then begin

    if 黑K[i] and CC[i]-進場價>20 or 前叉[i]=-1 then begin

      持倉:=0; 出訊[i]:=1;

    end else if CC[i]<停損價 then begin

      持倉:=0; 停損訊[i]:=1;

    end;

  end;

end;



//輸出訊號

DRAWICON(進訊,L,4) pxdn20;

DRAWICON(出訊,H,5) pxup45;

DRAWICON(停損訊,H,12) pxup45;

由 hwyhon 在 2010-01-15 18:44 發表:

請問版主

我的意思就是想表達出此情形
若類似此狀況的情行
如不用打回圈的方式
單靠舊函數有何投機的辦法做到嗎

由 cgjj 在 2010-01-15 19:21 發表:

引用:
最初由 hwyhon 發表
請問版主

我的意思就是想表達出此情形
若類似此狀況的情行
如不用打回圈的方式
單靠舊函數有何投機的辦法做到嗎


這狀況恐怕僅適合以迴圈處理
原因在於有累算問題

拿 EMA 來解說一下

EMA 算法:
若Y=EMA(X,N)
則Y=[2*X+(N-1)*Y']/(N+1), 其中Y'表示上一週期Y值。

Y' 就是我說的累算狀況
以 YY:EMA(C,N); 為例
自寫公式另算的方法如下:
原碼:


XX:=C;

StNo:=lbound(XX);

YY:C*0;

YY[StNo]:=XX[StNo];

for I=StNo+1 to datacount do begin

  YY[I]:=(2*XX[i]+(N-1)*YY[I-1])/(N+1);

end;
以您後面此例而言
必須確立前面已經 (停損 or 停利 or 出場) 了
才能決定後面進場要不要被成立
與 EMA 之 Y' 的累算狀況是同樣的

由 cgjj 在 2010-01-15 19:52 發表:

簡單來說

基本的進場訊號和出場訊號被定義出來後(非控損控盈出)
濾除連續相同重複訊號, 整合為一進一出後
以這一進一出為波段主軸, 做每一波的操作
再依據該波的績效做控損和控盈
若這波達控損或控盈就提前出場, 等下一波段來了再做(一波段只做一次)
這類指標可用您首例的方法來處理
這類指標訊號較少, 最明顯的例子
就是採均線黃金交叉和死亡交叉做進出

另一類
進場條件被定義出來後
控損控盈或碰出場訊號後, 就出場
若再碰進場條件, 則立即又進場
重複訊號是依據當前有無持倉來決定去留
這類並沒有定義出波段主軸, 每個進訊都可能成為新的一波
這類指標通常訊號較前類來的多(一波段戰鬥很多回)
您的第二例就是如此
這類必需採迴圈處理(因為要知道前面最後的倉位狀態)

不同指標特質不同, 處理手法會有差異
過濾訊號的先後次序與方法, 也是會帶來重大改變
兩類指標各有喜好者, 全看設計者自己想法

由 hwyhon 在 2010-01-16 09:03 發表:

感謝板主對這要兩個完全不一樣的進出法以程式做作詳解
解除我以往必須以舊函數一回接續一回才能完成的窘境與疑惑
再次謝謝您

__________________

就是發蓊梨(ㄛㄥˇ ㄌㄞˊ) 程式交易網站
[教學]指標公式及程式交易系統撰寫 [代工]

學會指標策略程式化的撰寫,將可讓你不再盲目投下辛苦賺來的血汗錢
要知道交易的策略或交易的模式長期執行下確實可獲利
交易才有意義的.否則寧可不交易


由 阿酷 在 2010-01-16 15:28 發表:

發表一下個人淺見
我不熟cgjj版主的迴圈寫法
我個人是以週期「先後」來比對，那個條件是「最近」成立的，來作為進出單的多空循環。
大意是把各個多空條件包括停利、損，都各別寫成、看成「自最先起始k線『至今』的『週期數』
再來比對，誰是『最後成立的』，那誰就是『最新』的訊號。
這樣寫法，也有利於寫績效回測價位，包括觸價。

__________________
永遠學習、學習永遠
善為傳家寶
忍為積德門

由 績效實戰派 在 2010-01-16 22:14 發表:

贊成

是用barslast這個函數比較先後成立順序.......最近成立的就是新訊號

我也是這樣寫給自動下單機的...

簡單又好用..

由 阿酷 在 2010-01-16 22:56 發表:

引用:
最初由 績效實戰派 發表
是用barslast這個函數比較先後成立順序.......最近成立的就是新訊號

我也是這樣寫給自動下單機的...

簡單又好用..

@@不簡單的實戰大，果然是奇狐類自動程式交易的佼佼者，佩服佩服。

__________________
永遠學習、學習永遠
善為傳家寶
忍為積德門

由 hwyhon 在 2010-01-17 01:44 發表:

依我淺見
版主的回答是正確的
因此例進場與出場都是不確定性的
除非如我想知的
有何方法把信號丟到程式頂端來供後續運算使用
依我所知barslast並無此功能阿
也因此可想像出用barslast處理出的信號

__________________

就是發蓊梨(ㄛㄥˇ ㄌㄞˊ) 程式交易網站
[教學]指標公式及程式交易系統撰寫 [代工]

學會指標策略程式化的撰寫,將可讓你不再盲目投下辛苦賺來的血汗錢
要知道交易的策略或交易的模式長期執行下確實可獲利
交易才有意義的.否則寧可不交易


由 阿酷 在 2010-01-17 17:54 發表:

引用:
最初由 hwyhon 發表
依我淺見
版主的回答是正確的
因此例進場與出場都是不確定性的
除非如我想知的
有何方法把信號丟到程式頂端來供後續運算使用
依我所知barslast並無此功能阿
也因此可想像出用barslast處理出的信號


ABC:IF(AA<>REF(AA,1),IF(A>B,1,0),REF(IF(A>B,1,0),BARSLAST(
AA<>REF(AA,1))));
如上例，我就是用這方式把訊號或者成立條件時的價位，「一直把前、後者成立」的所得「延續」
這方法是否同您要的「把信號丟到程式頂端來供後續運算使用」，小弟才挫僅供您參考。

__________________
永遠學習、學習永遠
善為傳家寶
忍為積德門

由 hwyhon 在 2010-01-17 18:42 發表:

能否請阿酷兄依此第二例子為例
完成信號的完整程式寫法提供參考

謝謝

__________________

就是發蓊梨(ㄛㄥˇ ㄌㄞˊ) 程式交易網站
[教學]指標公式及程式交易系統撰寫 [代工]

學會指標策略程式化的撰寫,將可讓你不再盲目投下辛苦賺來的血汗錢
要知道交易的策略或交易的模式長期執行下確實可獲利
交易才有意義的.否則寧可不交易


由 ifuian 在 2010-01-18 14:46 發表:

引用:
最初由 阿酷 發表
ABC:IF(AA<>REF(AA,1),IF(A>B,1,0),REF(IF(A>B,1,0),BARSLAST(
AA<>REF(AA,1))));
如上例，我就是用這方式把訊號或者成立條件時的價位，「一直把前、後者成立」的所得「延續」
這方法是否同您要的「把信號丟到程式頂端來供後續運算使用」，小弟才挫僅供您參考。


加入追蹤行列.

__________________
人外有人 天外有天 不懼不貪 亦富亦安

由 linsjn 在 2010-01-29 08:25 發表:

請問總版主:這種語法套用後run了幾次5分K15分K週期出現"指標數組下標越界或超出有效區間".沒顯示任何圖形而30分K以上正常.是什麼狀況.問題在那?

由 hwyhon 在 2010-01-29 08:54 發表:

您可能於套用的條件裡沒加
or barpos=0

__________________

就是發蓊梨(ㄛㄥˇ ㄌㄞˊ) 程式交易網站
[教學]指標公式及程式交易系統撰寫 [代工]

學會指標策略程式化的撰寫,將可讓你不再盲目投下辛苦賺來的血汗錢
要知道交易的策略或交易的模式長期執行下確實可獲利
交易才有意義的.否則寧可不交易


由 cgjj 在 2010-01-29 10:23 發表:

引用:
最初由 linsjn 發表
請問總版主:這種語法套用後run了幾次5分K15分K週期出現"指標數組下標越界或超出有效區間".沒顯示任何圖形而30分K以上正常.是什麼狀況.問題在那?


金叉 和 死叉 數據有效起始點不同, 故需要先用 or barpos=0 處理過
讓兩者數據有效起始點一樣, 如此跑迴圈才不會超出有效區間
金叉:CROSS(B,D) or barpos=0;
死叉:CROSS(D,B) or barpos=0;

若不是這問題, 則可能是您其它的程式碼所引發的問題

由 taiwanyang121 在 2010-06-28 01:28 發表:

sum(進訊,金叉SP+1)>0????????? 的意義 為何

由 cgjj 在 2010-06-28 09:43 發表:

引用:
最初由 taiwanyang121 發表
sum(進訊,金叉SP+1)>0????????? 的意義 為何


sum(進訊,n)>0
用於統計n根內是否有進訊

由 taiwanyang121 在 2010-06-28 18:08 發表:

問題

???????進訊:=B上揚 and 前叉=1 or BARPOS=0;???????
為何只有在初始時使用 條件件數列時才要加 or barpos=0;
是否因為條件數列與k棒數列不相關才要自行定義它相關的兩個條件與位置數列,對嗎??

例如 下一行是取的進訊數列
進訊:=B上揚 and 前叉=1 or BARPOS=0;
下一行是取的條件成立的位置數列
進訊SP:=BARSLAST(進訊<>0);
===============================================
barpos=1 代表計算的K棒是歷史首根
barpos=2 代表計算的K棒是歷史第二根

barpos=0 這情況是永不發生的

or barpos=0 是一種取巧的寫法
有時數列有效起始位置, 未必等於1 (歷史首根)
可能會是自第n根開始才有效
or barpos=0 會讓無效的部份填零
經過 or barpos=0 數列起點就會變為自1 開始(歷史首根)

此種取巧寫法
僅適用於數列中僅有 0 與 1 兩種值的情況下
====================================

由 cgjj 在 2010-06-28 18:25 發表:

引用:
最初由 taiwanyang121 發表
為何只有在初始時使用 條件件數列時才要加 or barpos=0;
???????進訊:=B上揚 and 前叉=1 or BARPOS=0;???????


barpos=1 代表計算的K棒是歷史首根
barpos=2 代表計算的K棒是歷史第二根

barpos=0 這情況是永不發生的

or barpos=0 是一種取巧的寫法
有時數列有效起始位置, 未必等於1 (歷史首根)
可能會是自第n根開始才有效
or barpos=0 會讓無效的部份填零
經過 or barpos=0 數列起點就會變為自1 開始(歷史首根)

此種取巧寫法
僅適用於數列中僅有 0 與 1 兩種值的情況下

由 taiwanyang121 在 2010-06-28 18:34 發表:

問題

是否因為條件數列與k棒數列不相關才要自行定義它相關的兩個條件與位置數列,對嗎??

例如 下一行是取的進訊數列
進訊:=B上揚 and 前叉=1 or BARPOS=0;
下一行是取的條件成立的位置數列
進訊SP:=BARSLAST(進訊<>0);

由 taiwanyang121 在 2010-06-28 18:40 發表:

問題

SUM(進訊,金叉SP+1)>0??????
經常看到範例中有些會+1 有些不會?? 是包含或不包含發生訊號當根k棒嗎???

由 cgjj 在 2010-06-28 18:50 發表:

引用:
最初由 taiwanyang121 發表
是否因為條件數列與k棒數列不相關才要自行定義它相關的兩個條件與位置數列,對嗎??

例如 下一行是取的進訊數列
進訊:=B上揚 and 前叉=1 or BARPOS=0;
下一行是取的條件成立的位置數列
進訊SP:=BARSLAST(進訊<>0);


條件數列與k棒數列是相關的

[進訊]這數列
是存那些位置有進場訊號 (有填1, 無填0)

[進訊SP]這數列
是存 [近期最近的進場訊號] 離當前這根有多遠
其通常會與 ref 會 sum 搭配使用

由 cgjj 在 2010-06-28 18:57 發表:

引用:
最初由 taiwanyang121 發表
SUM(進訊,金叉SP+1)>0??????
經常看到範例中有些會+1 有些不會?? 是包含或不包含發生訊號當根k棒嗎???


進訊SP 若等於 0 代表當根本身有進場訊號

進價:=ref(C,進訊SP);
這行可取得進場那根的收盤價

[金叉SP] 這數列
是存 [近期最近的金叉訊號] 離當前這根有多遠
金叉SP 若等於 0 代表當根本身有金叉訊號

SUM(進訊,金叉SP+1)>0
是用來判斷到近期發生金叉的範圍內是否有進訊產生

SUM(X,N)
當 N 值為零時, 代表加總 ALL
也就是自歷史首根加到當前這根

SUM(X,1) 只加總當根自己
SUM(X,2) 只加總當根自己和其前一根
故要將 金叉SP +1 後 才是我們要算的範圍

由 taiwanyang121 在 2010-06-28 19:09 發表:

贊成

感謝你,,加入奇狐快半年了 現在才知道奇狐家族的溫暖與強大

由 taiwanyang121 在 2010-06-28 19:25 發表:

//過濾連續進和連續出
CK:=進訊-出訊;
CK:=向前引用(CK,上一次條件成立位置(CK<>0));
CK:=條件函數(CK<>向前引用(CK,1) or 數據位置=序列下界(CK),CK,0);
進訊:=CK=1;
出訊:=CK=-1;
=========================
真的搞清楚 CK 有那麼多的等於及運算
能否說明清楚一下他的每一行用意和資料結構
例如: CK:=進訊-出訊;
是否作為0 表示有連續進出 的數列????

CK:=REF(CK,BARSLAST(CK<>0));
是否向前引用沒有連續進出的CK值???但想不出他的用處及資料結構會變成甚麼???????

由 cgjj 在 2010-06-29 15:29 發表:

引用:
最初由 taiwanyang121 發表
//過濾連續進和連續出
CK:=進訊-出訊;
CK:=向前引用(CK,上一次條件成立位置(CK<>0));
CK:=條件函數(CK<>向前引用(CK,1) or 數據位置=序列下界(CK),CK,0);
進訊:=CK=1;
出訊:=CK=-1;
=========================
真的搞清楚 CK 有那麼多的等於及運算
能否說明清楚一下他的每一行用意和資料結構
例如: CK:=進訊-出訊;
是否作為0 表示有連續進出 的數列????

CK:=REF(CK,BARSLAST(CK<>0));
是否向前引用沒有連續進出的CK值???但想不出他的用處及資料結構會變成甚麼???????


請見這的答覆
http://www.chiefox.com.tw/bbs/showt...59566#post59566
全部時間均為台灣時間, 現在時間為02:46
在這個頁面顯示本主題全部的 36 個文章


Powered by: vBulletin Version 2.3.0 - Copyright©2000-, Jelsoft Enterprises Limited.
簡愛洋行 製作 Copyright 2003-. All Rights Reserved.