奇狐社區論壇 - 交易利潤

奇狐社區論壇 (http://www.chiefox.com.tw/bbs/index.php)
- 問題交流 (http://www.chiefox.com.tw/bbs/forumdisplay.php?forumid=28)
-- 交易利潤_[多空交易範例] (http://www.chiefox.com.tw/bbs/showthread.php?threadid=13489)

由 kaiserlai 在 2010-04-21 12:15 發表:

交易利潤

HIHI
請問一下
奇狐裡的函數有可以return contract profit這樣的東西嗎?

謝謝

由 cgjj 在 2010-04-22 11:43 發表:

回覆: 交易利潤

引用:
最初由 kaiserlai 發表
HIHI
請問一下
奇狐裡的函數有可以return contract profit這樣的東西嗎?

謝謝

要麻煩您說明清楚何謂 return contract profit

每套分析軟體運算結構方法不盡相同
隨之處理的流程與方式自然也會不一樣

建議您最好針對您想做內容的提問
而非去問有無相似這樣的東西

因為同樣的東西或是名稱相等的函數
有可能會因為軟體運算流程方式不同
因而產生出不一樣的運算結果

由 kaiserlai 在 2010-04-23 17:26 發表:

CGJJ您好
我的想法是
假設我的進場點是5MA CROSS ABOVE 20MA就買進
停損點設30點
但是如果獲利超過30點，則停損縮窄為10點。
做空的話就是5MA CROSS BELOW 20MA，停損點的設置同上。

大概是這樣的概念。

謝謝!

由 cgjj 在 2010-04-26 18:11 發表:

引用:
最初由 kaiserlai 發表
CGJJ您好
我的想法是
假設我的進場點是5MA CROSS ABOVE 20MA就買進
停損點設30點
但是如果獲利超過30點，則停損縮窄為10點。
做空的話就是5MA CROSS BELOW 20MA，停損點的設置同上。

大概是這樣的概念。

謝謝!

對看看是為您要的結果

原碼:


CC:=C;

MA5:MA(C,5);

MA20:MA(C,20);

多進:=cross(MA5,MA20) or barpos=0;

空進:=cross(MA20,MA5) or barpos=0;



進出:C*0 NOAXIS;

多空:=0; 進價:=0; 盈虧:c*0 linethick;

for i = 1 to datacount do begin

  if 多空=0 then begin

    多空:=多進[i]-空進[i]; 進出[i]:=多空;

    if 多空<>0 then begin

      進價:=CC[i]; 控損:=30;

    end;

  end else if 多空<>0 then begin

    盈虧[i]:=(CC[i]-進價)*多空;

    if 盈虧[i]>30 then 控損:=10;

    if 多空=空進[i] or 多空=-多進[i] then begin

      進出[i]:=-多空*3; 多空:=-多空; 

      進價:=CC[i]; 控損:=30;

    end else if 盈虧[i]<=-控損 then begin

      進出[i]:=多空*2; 多空:=0;

    end;

  end;

end;

[進出] 這變數值代表意義如下:
1.多單進場, 2.多控損出 , 3.空轉多
-1.空單進場,-2.空控損出, -3.多轉空

由 kaiserlai 在 2010-04-27 15:26 發表:

總版主你好
這公式這樣沒錯
不過如果我的挺損點要用非常數請問怎麼寫?
比方說
1.
假設我的進場點是5MA CROSS ABOVE 20MA就買進
停損點設ATR(average true range)
但是如果獲利超過ATR的3倍，則停損縮窄為ATR
做空的話就是5MA CROSS BELOW 20MA，停損點的設置同上。

以及
2.
假設我要加入當沖強制平倉
8:50後才引發買賣訊
13:40強制出場
請問該怎麼寫?
我搜索了一下論壇
發現應該加入

強出:=time>=134000;
限進:=time<=085000;

這兩行指令，但是因為對迴圈不熟所以還不曉得要放哪邊

麻煩您了!

由 cgjj 在 2010-04-28 09:09 發表:

引用:
最初由 kaiserlai 發表
總版主你好
這公式這樣沒錯
不過如果我的挺損點要用非常數請問怎麼寫?
比方說
1.
假設我的進場點是5MA CROSS ABOVE 20MA就買進
停損點設ATR(average true range)
但是如果獲利超過ATR的3倍，則停損縮窄為ATR
做空的話就是5MA CROSS BELOW 20MA，停損點的設置同上。

以及
2.
假設我要加入當沖強制平倉
8:50後才引發買賣訊
13:40強制出場
請問該怎麼寫?
我搜索了一下論壇
發現應該加入

強出:=time>=134000;
限進:=time<=085000;

這兩行指令，但是因為對迴圈不熟所以還不曉得要放哪邊

麻煩您了!

停損點設ATR(average true range)
但是如果獲利超過ATR的3倍，則停損縮窄為ATR

這樣豈不是獲利有無超過ATR的3倍, 都是用 ATR 這個值了嗎

由 kaiserlai 在 2010-04-28 09:15 發表:

不好意思
應該是初使停損是ATR*3
如果獲利超過ATR*3
停損變成ATR

這樣才對
謝謝!

由 cgjj 在 2010-04-28 09:46 發表:

引用:
最初由 kaiserlai 發表
不好意思
應該是初使停損是ATR*3
如果獲利超過ATR*3
停損變成ATR

這樣才對
謝謝!

停損計算之ATR, 是進場那根的 ATR 值嗎? (水平線)
還是隨行情變化, 採用當前這根的ATR 值? (曲線)

由 kaiserlai 在 2010-04-28 09:51 發表:

我本來的想法是隨著行情變化調整ATR(也就是曲線)
但是版主您的想法很有趣所以我想兩種都測看看，
而且這兩個的迴圈各應該怎麼寫我也非常好奇
可以跟您請教這兩種個別的寫法嗎?

由 cgjj 在 2010-04-28 10:32 發表:

引用:
最初由 kaiserlai 發表
我本來的想法是隨著行情變化調整ATR(也就是曲線)
但是版主您的想法很有趣所以我想兩種都測看看，
而且這兩個的迴圈各應該怎麼寫我也非常好奇
可以跟您請教這兩種個別的寫法嗎?

方式1:
停損計算之ATR, 是進場那根的 ATR 值(水平線)
註: ATR 請自行帶入公式之中

原碼:


CC:=C;

MA5:MA(C,5);

MA20:MA(C,20);

強出:=time>=134000;

限進:=time<=085000;

多進:=cross(MA5,MA20) and 強出=0 and 限進=0 or barpos=0;

空進:=cross(MA20,MA5) and 強出=0 and 限進=0 or barpos=0;

進出:C*0 NOAXIS;

多空:=0; 進價:=0; 盈虧:c*0 linethick;

for i = 1 to datacount do begin

  if 多空=0 then begin

    多空:=多進[i]-空進[i]; 進出[i]:=多空;

    if 多空<>0 then begin

      進價:=CC[i]; 進ATR:=ATR[i];

    end;

  end else if 多空<>0 then begin

    盈虧[i]:=(CC[i]-進價)*多空;    

    if 盈虧[i]>ATR[i]*3 then begin

      控損:=進ATR;

    end else begin

      控損:=進ATR*3;

    end;

    if 強出[i] then begin

      進出[i]:=多空*3; 多空:=0;

    end else if 多空=空進[i] or 多空=-多進[i] then begin

      進出[i]:=-多空*4; 多空:=-多空;

      進價:=CC[i]; 進ATR:=ATR[i];

    end else if 盈虧[i]<=-控損 then begin

      進出[i]:=多空*2; 多空:=0;

    end;

  end;

end;

[進出] 這變數值代表意義如下:
1.多單進場, 2.多控損出 , 3.多強出 , 4.空轉多
-1.空單進場, -2.空控損出, -3.空強出 , -4.多轉空

由 cgjj 在 2010-04-28 10:38 發表:

方式2:
隨行情變化, 採用當前這根的ATR 值(曲線)
註: ATR 請自行帶入公式之中

原碼:


CC:=C;

MA5:MA(C,5);

MA20:MA(C,20);

強出:=time>=134000;

限進:=time<=085000;

多進:=cross(MA5,MA20) and 強出=0 and 限進=0 or barpos=0;

空進:=cross(MA20,MA5) and 強出=0 and 限進=0 or barpos=0;

進出:C*0 NOAXIS;

多空:=0; 進價:=0; 盈虧:c*0 linethick;

for i = 1 to datacount do begin

  if 多空=0 then begin

    多空:=多進[i]-空進[i]; 進出[i]:=多空;

    if 多空<>0 then 進價:=CC[i];

  end else if 多空<>0 then begin

    盈虧[i]:=(CC[i]-進價)*多空;    

    if 盈虧[i]>ATR[i]*3 then begin

      控損:=ATR[i];

    end else begin

      控損:=ATR[i]*3;

    end;

    if 強出[i] then begin

      進出[i]:=多空*3; 多空:=0;

    end else if 多空=空進[i] or 多空=-多進[i] then begin

      進出[i]:=-多空*4; 多空:=-多空;

      進價:=CC[i];

    end else if 盈虧[i]<=-控損 then begin

      進出[i]:=多空*2; 多空:=0;

    end;

  end;

end;

[進出] 這變數值代表意義如下:
1.多單進場, 2.多控損出 , 3.多強出 , 4.空轉多
-1.空單進場, -2.空控損出, -3.空強出 , -4.多轉空

由 kaiserlai 在 2010-04-28 10:46 發表:

謝謝你!

由 kaiserlai 在 2010-04-28 15:04 發表:

版主你好
我剛才試驗了一下
發現他的停損不會跟移動
也就是說
當做多時，如果行情繼續走高
則停損點回持續走高

比方說
作多在7000
停損50點:6950回停損
如果行情走到7100，則停損也移到7050

請問這樣的話要怎麼改迴圈?

由 kaiserlai 在 2010-04-28 18:06 發表:

版主
不好意思
順便問一下
上面的公式沒有有加入強進、強出

強出:=time>=134000;
限進:=time<=085000;

的寫法該是怎麼樣?

因為想兩種都測試一下
謝謝!

由 cgjj 在 2010-04-29 00:15 發表:

引用:
最初由 kaiserlai 發表
版主你好
我剛才試驗了一下
發現他的停損不會跟移動
也就是說
當做多時，如果行情繼續走高
則停損點回持續走高

比方說
作多在7000
停損50點:6950回停損
如果行情走到7100，則停損也移到7050

請問這樣的話要怎麼改迴圈?

方式一不會跟著移動
方式二會跟著ATR移動

由 cgjj 在 2010-04-29 00:16 發表:

引用:
最初由 kaiserlai 發表
版主
不好意思
順便問一下
上面的公式沒有有加入強進、強出

強出:=time>=134000;
限進:=time<=085000;

的寫法該是怎麼樣?

因為想兩種都測試一下
謝謝!

前面給的兩個方式已經有處理到強出和限進了唷

由 mori868 在 2010-04-29 07:28 發表:

引用:
最初由 cgjj 發表
停損點設ATR(average true range)
但是如果獲利超過ATR的3倍，則停損縮窄為ATR

這樣豈不是獲利有無超過ATR的3倍, 都是用 ATR 這個值了嗎

ATR如何設請做一範例

由 kaiserlai 在 2010-04-29 18:45 發表:

版主你好
請問要怎麼樣可以像"進出"、"盈虧"
一樣顯示出停損點𡧛指數位置?

謝謝

由 cgjj 在 2010-04-30 08:28 發表:

引用:
最初由 kaiserlai 發表
版主你好
請問要怎麼樣可以像"進出"、"盈虧"
一樣顯示出停損點𡧛指數位置?

謝謝

以方式一為例

原碼:


CC:=C;

MA5:MA(C,5);

MA20:MA(C,20);

強出:=time>=134000;

限進:=time<=085000;

多進:=cross(MA5,MA20) and 強出=0 and 限進=0 or barpos=0;

空進:=cross(MA20,MA5) and 強出=0 and 限進=0 or barpos=0;

進出:C*0 NOAXIS;

多空:=0; 進價:=0; 盈虧:c*0 linethick;

控損值:c*0 linethick;

for i = 1 to datacount do begin

  if 多空=0 then begin

    多空:=多進[i]-空進[i]; 進出[i]:=多空;

    if 多空<>0 then begin

      進價:=CC[i]; 進ATR:=ATR[i];

    end;

  end else if 多空<>0 then begin

    盈虧[i]:=(CC[i]-進價)*多空;    

    if 盈虧[i]>ATR[i]*3 then begin

      控損:=進ATR;

    end else begin

      控損:=進ATR*3;

    end;

    if 強出[i] then begin

      進出[i]:=多空*3; 多空:=0;

    end else if 多空=空進[i] or 多空=-多進[i] then begin

      進出[i]:=-多空*4; 多空:=-多空;

      進價:=CC[i]; 進ATR:=ATR[i];

    end else if 盈虧[i]<=-控損 then begin

      進出[i]:=多空*2; 多空:=0;

    end;

  end;

  控損值[i]:=控損;

end;

由 cgjj 在 2010-04-30 08:29 發表:

引用:
最初由 mori868 發表
ATR如何設請做一範例

ATR 是內建指標

由 kaiserlai 在 2010-05-04 17:05 發表:

版主你好

我在迴圈之前加入這兩行公式

TR:MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW)),linethick0;

ATR:ma(TR,12);

公式其他部分跟版主你說的一樣
但是我發現控損值都是一個固定值，不會隨著行情變化
請問要怎麼修改??

由 cgjj 在 2010-05-05 14:42 發表:

引用:
最初由 kaiserlai 發表
版主你好

我在迴圈之前加入這兩行公式

TR:MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW)),linethick0;

ATR:ma(TR,12);

公式其他部分跟版主你說的一樣
但是我發現控損值都是一個固定值，不會隨著行情變化
請問要怎麼修改??

是會跟著變的唷
給您的範例, 是以方式一為例的
其是, 一回交易一個數值(梯狀線)

同樣的改法應用到方式二
就會隨行情時時變(曲狀線)

由 kaiserlai 在 2010-05-06 11:39 發表:

版主
不好意思
我又回去研究了一下
發現假如作多進場8000點，ATR*3=30點
所以當利潤=-30的時候會停損
但是我的想法是
如果有獲利的話，停損的點會一直往上(作多)
比方說
8000做多，獲利100點(現在8100點)

那停損應該要變成8100-10=8090(因為獲利超過ATR的3倍)

請問這樣該怎麼寫

謝謝!

由 cgjj 在 2010-05-06 12:11 發表:

引用:
最初由 kaiserlai 發表
版主
不好意思
我又回去研究了一下
發現假如作多進場8000點，ATR*3=30點
所以當利潤=-30的時候會停損
但是我的想法是
如果有獲利的話，停損的點會一直往上(作多)
比方說
8000做多，獲利100點(現在8100點)

那停損應該要變成8100-10=8090(因為獲利超過ATR的3倍)

請問這樣該怎麼寫

謝謝!

先想想一個問題
8100 點是當下的行情(Close)
用當下的 Close價減掉 N點當停損值
是永遠無法產生停損動作的

由 kaiserlai 在 2010-05-06 12:20 發表:

版主您說的沒錯
所以應該是前一個收盤8100
然後再用這個值減10點
這樣才會有停利的動作出現

謝謝!

由 kaiserlai 在 2010-05-06 12:27 發表:

對不起邏輯應該修正一下
停損點應該要考慮行情位置
假如8000買進，漲到8100最高
那應該是以8100(也就是從買進到目前的最高點)當基準點
減去ATR，這樣才對

謝謝

由 cgjj 在 2010-05-06 16:13 發表:

引用:
最初由 kaiserlai 發表
對不起邏輯應該修正一下
停損點應該要考慮行情位置
假如8000買進，漲到8100最高
那應該是以8100(也就是從買進到目前的最高點)當基準點
減去ATR，這樣才對

謝謝

原碼:


TR1:=MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW)),linethick0;

ATR:=ma(TR1,12);

CC:=C;

MA5:MA(C,5);

MA20:MA(C,20);

強出:=time>=134000;

限進:=time<=085000;

多進:=cross(MA5,MA20) and 強出=0 and 限進=0 or barpos=0;

空進:=cross(MA20,MA5) and 強出=0 and 限進=0 or barpos=0;

進出:C*0 NOAXIS;

多空:=0; 進價:=0; 盈虧:c*0 linethick;

控損價:c*0 linethick;

for i = 1 to datacount do begin

  if 多空=0 then begin

    多空:=多進[i]-空進[i]; 進出[i]:=多空;

    if 多空<>0 then begin

      進價:=CC[i]; 進HL:=CC[i];

    end;

  end else if 多空<>0 then begin

    if CC[i]*多空>進HL*多空 then 進HL:=CC[i];

    盈虧[i]:=(CC[i]-進價)*多空;

    if 盈虧[i]>ATR[i]*3 then begin

      控損P:=進HL-ATR[i]*多空;

    end else begin

      控損P:=進HL-ATR[i]*多空*3;

    end;

    if 強出[i] then begin

      進出[i]:=多空*3; 多空:=0;

    end else if 多空=空進[i] or 多空=-多進[i] then begin

      進出[i]:=-多空*4; 多空:=-多空;

      進價:=CC[i]; 進HL:=CC[i];

    end else if CC[i]*多空<=控損P*多空 then begin

      進出[i]:=多空*2; 多空:=0;

    end;

    控損價[i]:=控損P;

  end;

end;

[進出] 這變數值代表意義如下:
1.多單進場, 2.多控損出 , 3.多強出 , 4.空轉多
-1.空單進場, -2.空控損出, -3.空強出 , -4.多轉空
//關鍵字:交易系統範例

由 kaiserlai 在 2010-05-06 16:44 發表:

版主謝謝你
請問可以把停損停利價PLOT在圖上嗎?

謝謝!

由 cgjj 在 2010-05-06 16:47 發表:

引用:
最初由 kaiserlai 發表
版主謝謝你
請問可以把停損停利價PLOT在圖上嗎?

謝謝!

把
控損價:c*0 linethick;
改為
控損價:c*0 ;
就可看到控制曲線嚕

由 kaiserlai 在 2010-05-10 11:36 發表:

版主
我發現控損價的值會根據當跟K線變動
所以控損價的邏輯應該是根據前一跟K線的CLOSE來減去ATR才對
請問一下要怎麼改?

另外不好意思一直麻煩您
請問有甚麼書或網站有在解說這個迴圈語法嗎?
PS:我本身會VBA，但是奇狐寫法我還不太會

由 cgjj 在 2010-05-10 12:22 發表:

引用:
最初由 kaiserlai 發表
版主
我發現控損價的值會根據當跟K線變動
所以控損價的邏輯應該是根據前一跟K線的CLOSE來減去ATR才對
請問一下要怎麼改?

另外不好意思一直麻煩您
請問有甚麼書或網站有在解說這個迴圈語法嗎?
PS:我本身會VBA，但是奇狐寫法我還不太會

依據前述
---------------------------------------------------------------------------------------------------
停損點應該要考慮行情位置
假如8000買進，漲到8100最高
那應該是以8100(也就是從買進到目前的最高點)當基準點
減去ATR，這樣才對
---------------------------------------------------------------------------------------------------
若當下行情是這波最高位置, 就會發生隨當根K線變動
若您要當根不列入計算
可試著將這行
if CC[i]*多空>進HL*多空 then 進HL:=CC[i];
改為
if CC[i-1]*多空>進HL*多空 then 進HL:=CC[i-1];

VBA 的陣列 CC(i) 就是奇狐中的 CC[i] , K棒資料就是陣列型態
VBA 中 i 自零數起, 奇狐中 i 自壹數起
相關教學可見此
http://www.chiefox.com.tw/bbs/forum...p?s=&forumid=46

由 soromance 在 2010-11-26 15:35 發表:

引用:

最初由 cgjj 發表
方式2:
隨行情變化, 採用當前這根的ATR 值(曲線)
註: ATR 請自行帶入公式之中

原碼:


CC:=C;

MA5:MA(C,5);

MA20:MA(C,20);

強出:=time>=134000;

限進:=time<=085000;

多進:=cross(MA5,MA20) and 強出=0 and 限進=0 or barpos=0;

空進:=cross(MA20,MA5) and 強出=0 and 限進=0 or barpos=0;

進出:C*0 NOAXIS;

多空:=0; 進價:=0; 盈虧:c*0 linethick;

for i = 1 to datacount do begin

  if 多空=0 then begin

    多空:=多進[i]-空進[i]; 進出[i]:=多空;

    if 多空<>0 then 進價:=CC[i];

  end else if 多空<>0 then begin

    盈虧[i]:=(CC[i]-進價)*多空;    

    if 盈虧[i]>ATR[i]*3 then begin

      控損:=ATR[i];

    end else begin

      控損:=ATR[i]*3;

    end;

    if 強出[i] then begin

      進出[i]:=多空*3; 多空:=0;

    end else if 多空=空進[i] or 多空=-多進[i] then begin

      進出[i]:=-多空*4; 多空:=-多空;

      進價:=CC[i];

    end else if 盈虧[i]<=-控損 then begin

      進出[i]:=多空*2; 多空:=0;

    end;

  end;

end;

[進出] 這變數值代表意義如下:
1.多單進場, 2.多控損出 , 3.多強出 , 4.空轉多
-1.空單進場, -2.空控損出, -3.空強出 , -4.多轉空

版主您好：

請問一下，在停損例子中，有用到：

進出:C*0 NOAXIS;
多空:=0; 進價:=0; 盈虧:c*0 linethick;

為何要進出:C*0 以及盈虧: C*0 這樣的寫法呢?
不是很瞭解..

謝謝您的解答.. ^^

由 cgjj 在 2010-11-26 16:02 發表:

引用:
最初由 soromance 發表
版主您好：

請問一下，在停損例子中，有用到：

進出:C*0 NOAXIS;
多空:=0; 進價:=0; 盈虧:c*0 linethick;

為何要進出:C*0 以及盈虧: C*0 這樣的寫法呢?
不是很瞭解..

謝謝您的解答.. ^^

創造一個與K棒同等長度的零值數列
100根K棒, 數列就有100個元素

由 soromance 在 2010-11-26 19:35 發表:

引用:
最初由 cgjj 發表
創造一個與K棒同等長度的零值數列
100根K棒, 數列就有100個元素

嗯，算是宣告陣列的意思嗎？
如果是如此的話，我們在程式中仍有看到

多進[i]、空進[i]、CC[i]、以及ATR[i]等，
為什麼這些參數就不需要創造與K棒等長度的零值數列呢？

不好意思，不是學程式出身的，問比較基本的問題。

Soro

由 cgjj 在 2010-11-29 09:26 發表:

引用:
最初由 soromance 發表
嗯，算是宣告陣列的意思嗎？
如果是如此的話，我們在程式中仍有看到

多進[i]、空進[i]、CC[i]、以及ATR[i]等，
為什麼這些參數就不需要創造與K棒等長度的零值數列呢？

不好意思，不是學程式出身的，問比較基本的問題。

Soro

因為多進, 空進, CC, ATR 這四個變數
在帶入迴圈前, 其本身存的內容就已經是數列型態了

全部時間均為台灣時間, 現在時間為23:43

在這個頁面顯示本主題全部的 35 個文章