奇狐社區論壇 - <分享>主圖的損益曲線圖

奇狐社區論壇 (http://www.chiefox.com.tw/bbs/index.php)
- 問題交流 (http://www.chiefox.com.tw/bbs/forumdisplay.php?forumid=28)
-- <分享>主圖的損益曲線圖 (http://www.chiefox.com.tw/bbs/showthread.php?threadid=6108)

由 *963. 在 2006-09-21 09:54 發表:

<分享>主圖的損益曲線圖

在下獻醜分享:主圖的損益曲線圖
答謝克拉克兄不吝惠賜1999-2001的台指歷史資料數據

只要您把邏輯設定好.績效.勝率.賺賠比.及損益曲線圖.
修改模組時在主圖上均可立即得知修改結果.方便大家編寫程式進度
範例為多空雙向,多單平倉=同時空單進場,
您可以在依您的策略自行修改:

//先定義您的多單及空單進場條件
多進:=
空進:=

//雙向損益計算
手續費:=3;
多補:=IF(空進>0,C,0),LINETHICK0;
多入:=IF(多補>0,REF(C,BARSLAST(多進)),0),LINETHICK0;
多單益:=IF(空進>0,多補-多入-手續費,0),LINETHICK1,COLORRED;
多總益:=SUM((多單益),0),LINETHICK0;

空補:=IF(多進>0,C,0),LINETHICK0;
空入:=IF(空補>0,REF(C,BARSLAST(空進)),0),LINETHICK0;
空單益:=IF(多進>0,空入-空補-手續費,0),LINETHICK1,COLORGREEN;
空總益:=SUM((空單益),0),LINETHICK0;

//雙向勝率&賺賠比
多賺趟:=SUM(IF(多單益>0,1,0),0),LINETHICK0;
多賠趟:=SUM(IF(多單益<0,1,0),0),LINETHICK0;
多勝率:=(多賺趟/(多賺趟+多賠趟))*100,LINETHICK0;
多賺:=SUM(IF(多單益>0 ,多單益,0),0),LINETHICK0;
多賠:=SUM(IF(多單益<0 ,多單益,0),0),LINETHICK0;
多賺賠比:100+(多賠/多賺)*100,LINETHICK0;

空賺趟:=SUM(IF(空單益>0,1,0),0),LINETHICK0;
空賠趟:=SUM(IF(空單益<0,1,0),0),LINETHICK0;
空勝率:=(空賺趟/(空賺趟+空賠趟))*100,LINETHICK0;
空賺:=SUM(IF(空單益>0 , 空單益,0),0),LINETHICK0;
空賠:=SUM(IF(空單益<0 , 空單益,0),0),LINETHICK0;
空賺賠比:100+(空賠/空賺)*100,LINETHICK0;

//總和數據
總勝率:(多勝率+空勝率)/2,LINETHICK0;
//EX:總勝率數據:65,指100次出手有65次為賺錢.數據愈高代表正確出手勝率愈好
總賺賠比: (多賺賠比+空賺賠比)/2,LINETHICK0;
//EX: 總賺賠比數據:75,每賺100元中有75元為淨賺.25元為停損所用.數據愈高代表大賺小賠的情狀愈好
總獲利曲線:多總益+空總益,LINETHICK1;//平穩成長為佳

由 ifuian 在 2006-09-21 10:47 發表:

QQQ

多謝了.

__________________
人外有人天外有天不懼不貪亦富亦安

由期靈王在 2006-09-21 16:26 發表:

回覆: <分享>主圖的損益曲線圖

[只要您把邏輯設定好.績效.勝率.賺賠比.及損益曲線圖.
修改模組時在主圖上均可立即得知修改結果.方便大家編寫程式進度

請問這句話是什麼意思
上面的程式要套用在哪
多進和空進要如何表達

由 peter109 在 2006-09-22 11:13 發表:

還在學習ing ....

感恩分享

__________________
至誠能勝天下至偽
至拙能勝天下至巧

由 *963. 在 2006-09-22 12:09 發表:

回覆<期靈王>大大

多進:=您的模組-多單進場的邏輯
空進:=您的模組-空單進場的邏輯

至於要如何給邏輯-就要看您自己給模組進出場的條件為何?

舉簡單的例子:

多進:=CROSS(C,MA(C,5)) and VOL>ref(VOL,1) ;
空進:=CROSS(MA(C,5),C) and VOL>ref(VOL,1);

由期靈王在 2006-09-22 13:05 發表:

這是一個獨立公式嗎
還是要放到其他公式中
要用到軟體哪些功能才能測試
用圖形說明比較清楚

由 *963. 在 2006-09-22 13:54 發表:

他是一個容器工具
附加在您想測試績效的模組後面

直接將績效數據表現在主圖上.不需再做其他功能的切換
修改的進度可立即得知.方便您邏輯的修改編寫

由期靈王在 2006-09-22 14:10 發表:

不怎麼好用
乾脆以解盤方式顯示就好
我一直獲利會使圖形壓縮變很小

由 *963. 在 2006-09-22 14:19 發表:

當然也是OK~

放主圖有對應型態的好處-對應模組在各種型態的表現
縮小顯示文字數據也可以

這個容器分享是幫助寫程式的朋友.不需在功能轉換
就可以在主圖看到模組進度

當然可以把容器依個人習慣-放在適合位置

大家加油吧~

由 c300_tw 在 2006-09-23 21:27 發表:

感謝分享

由 afala 在 2006-09-24 10:24 發表:

引用:
最初由 *963. 發表
舉簡單的例子:

多進:=CROSS(C,MA(C,5)) and VOL>ref(VOL,1) ;
空進:=CROSS(MA(C,5),C) and VOL>ref(VOL,1);

*963兄:
請教一下
如何把交易訊號寫在穿越點上(如您的例子-價位穿越5MA)
而不是收盤價
感謝!

由 *963. 在 2006-09-25 12:03 發表:

回覆afala兄:

做交易系統.要思考實際進場的執行節奏性

為避免盤中上下影線穿越的假訊號

一般而言會以收盤價或下一根K棒的開盤做為進場價

提供給您參考

由 yuting_lin 在 2006-09-25 14:18 發表:

感謝分享!!

由 afala 在 2006-09-25 16:51 發表:

引用:
最初由 *963. 發表
回覆afala兄:

做交易系統.要思考實際進場的執行節奏性

為避免盤中上下影線穿越的假訊號

一般而言會以收盤價或下一根K棒的開盤做為進場價

提供給您參考

感謝*963兄的回應!
我會想做到[盤中點價]即出現訊號
是因為常常收盤跟點的訊號價位差太多而
影響了績效啊!

真的有效的點,常常是噴出點
等待收盤才出現訊號,真的差太多啦

由 *963. 在 2006-09-25 17:29 發表:

回覆afala兄:

聽您所言您應當是做日線模組

盤中點到不等收盤即有訊號寫法.試試把CROSS(C,MA(C,5))
改成CROSS(H ,MA(C,5)).盤中的高低碰到就成立

依經驗這樣的進場執行-建議搭配當天的停損計畫

您在參考測試看看

由 kokyo 在 2006-10-05 11:46 發表:

*963兄您好，
如果只要計算近3年內的資料(當天往前算3年)，您的程式應該要怎麼改呢？

由 *963. 在 2006-10-05 12:14 發表:

在下的作法是:

把要計算的週期使用匯出匯入的功能
單獨成立一個自定義市場K線
例如:2003-2005
數據匯入教學請在論壇搜尋

這樣可避免最近的K線加入影響模組測試

建議您先不把最近1.2年的K線放入
等您的模組告一段落.再將後面的K線當做模擬測試

如果2段K線的獲利率&賺賠比之年數據不會落差5%以上.
恭喜您的模組已經趨近成熟

由 kokyo 在 2006-10-06 04:15 發表:

原來如此，多謝了。

由 afala 在 2006-10-15 16:41 發表:

引用:
最初由 *963. 發表

聽您所言您應當是做日線模組

盤中點到不等收盤即有訊號寫法.試試把CROSS(C,MA(C,5))
改成CROSS(H ,MA(C,5)).盤中的高低碰到就成立

依經驗這樣的進場執行-建議搭配當天的停損計畫

您在參考測試看看

*963兄:
感謝您的指導,終於解決此問題了

另外又有一個問題請教:
如已經有多進訊號,如CROSS(H,MA(C,5))
在沒有出現反向空進訊號,而又出現多進訊號
則會以新的多進訊號為進場點
如何做到沒有出現反向空進訊號時,不會再出現多進訊號?
感謝!!

由 yuting_lin 在 2007-01-07 14:58 發表:

引用:
最初由 kokyo 發表
*963兄您好，
如果只要計算近3年內的資料(當天往前算3年)，您的程式應該要怎麼改呢？

如下即可, 跨年才完成的交易應該是會被算在新的一年裡

//先定義您的多單及空單進場條件
多進:=
空進:=
起算年:=2006;
YYY:Year>(起算年-1);

//雙向損益計算
手續費:=3;
多補:=IF(空進>0 and YYY,C,0),LINETHICK0;
多入:=IF(多補>0 and YYY,REF(C,BARSLAST(多進)),0),LINETHICK0;
多單益:=IF(空進>0 and YYY,多補-多入-手續費,0),LINETHICK1,COLORRED;
多總益:=SUM((多單益),0),LINETHICK0;

空補:=IF(多進>0 and YYY,C,0),LINETHICK0;
空入:=IF(空補>0 and YYY,REF(C,BARSLAST(空進)),0),LINETHICK0;
空單益:=IF(多進>0 and YYY,空入-空補-手續費,0),LINETHICK1,COLORGREEN;
空總益:=SUM((空單益),0),LINETHICK0;

全部時間均為台灣時間, 現在時間為06:18

在這個頁面顯示本主題全部的 20 個文章