奇狐社區論壇 - 關於前高的寫法

奇狐社區論壇 (http://www.chiefox.com.tw/bbs/index.php)
- 問題交流 (http://www.chiefox.com.tw/bbs/forumdisplay.php?forumid=28)
-- 關於前高的寫法 (http://www.chiefox.com.tw/bbs/showthread.php?threadid=21840)

由 picabu 在 2019-04-06 15:37 發表:

關於前高的寫法

請問版主關於A高點的寫法我是用
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);

MUP:= CROSS(MACD,0);
A高:= HHV(H,BARSLAST(MUP));

如果我想要求下一個MACD轉正的高點大於A高(也就是C高),而不是B高的寫法,該如何表述呢?謝謝.

由 cgjj 在 2019-04-08 09:26 發表:

回覆: 關於前高的寫法

引用:
最初由 picabu 發表
請問版主關於A高點的寫法我是用
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);

MUP:= CROSS(MACD,0);
A高:= HHV(H,BARSLAST(MUP));

如果我想要求下一個MACD轉正的高點大於A高(也就是C高),而不是B高的寫法,該如何表述呢?謝謝.

原碼:DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);

MUP:=CROSS(MACD,0); MUPSP:=BARSLAST(MUP);
MDN:=CROSS(0,MACD); MDNSP:=BARSLAST(MDN);
M高:=HHV(H,MUPSP+1) linethick0;
if lbound(MDNSP)=0 then exit; //跳離
PP:=datacount-MDNSP[datacount]-1;
A高:M高[PP] linethick0;
前高:0 linethick;
for i= PP downto lbound(MDNSP) do begin
  i:=i-MDNSP[i]-1;
  if M高[i]>A高 then begin
    前高:=M高[i]; break;
  end;
end;

由 picabu 在 2019-04-08 18:18 發表:

謝謝大大的回覆,問題解決了.還有一個小問題就是,已經取得上個高點C的價位,那如何知道該價位距離目前的ˋ週期數呢?

由 cgjj 在 2019-04-09 11:19 發表:

引用:
最初由 picabu 發表
謝謝大大的回覆,問題解決了.還有一個小問題就是,已經取得上個高點C的價位,那如何知道該價位距離目前的ˋ週期數呢?:D

原碼:DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
MUP:=CROSS(MACD,0); MUPSP:=BARSLAST(MUP);
MDN:=CROSS(0,MACD); MDNSP:=BARSLAST(MDN);
M高SP:=HHVBARS(H,MUPSP+1);
M高:=ref(H,M高SP);
if lbound(MDNSP)=0 then exit; //跳離
PP:=datacount-MDNSP[datacount]-1;
A高:M高[PP] linethick0;
前高:0 linethick; 前高POS:=0;
for i= PP downto lbound(MDNSP) do begin
  i:=i-MDNSP[i]-1;
  if M高[i]>A高 then begin
    前高:=M高[i]; 前高POS:=i-M高SP[i];break;
  end;
end;
前高SP:barslast(barpos=前高POS)linethick;

由 picabu 在 2019-04-09 16:36 發表:

謝謝總版大

由 picabu 在 2019-04-12 16:02 發表:

再請教總版大一下,A高SP的表達是?

A高SP:HHVBARS(H,MUPSP+1);
這樣正確嗎?

由 cgjj 在 2019-04-12 17:08 發表:

引用:
最初由 picabu 發表
再請教總版大一下,A高SP的表達是?

A高SP:HHVBARS(H,MUPSP+1);
這樣正確嗎?

A高SP:barslast(barpos=PP-M高SP[PP]);

由 picabu 在 2019-04-12 17:43 發表:

謝謝您的修正, 感恩.

由 picabu 在 2019-04-15 14:55 發表:

總版主您好,今天把上面的公式運用在操盤指標中的主圖加跌,發現以致茂(2360)為例會出現如附圖的"操盤指標數組下標越界或超出有效數據區間".看起來好像是找不到c高點.如果是這樣可以幫我修改成如果找不到C高點,就以前高=A高為高點,麻煩您
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
MUP:=CROSS(MACD,0); MUPSP:=BARSLAST(MUP);
MDN:=CROSS(0,MACD); MDNSP:=BARSLAST(MDN);
M高SP:=HHVBARS(H,MUPSP+1);
M高:=ref(H,M高SP);
if lbound(MDNSP)=0 then exit; //跳離
PP:=datacount-MDNSP[datacount]-1;
A高:=M高[PP] linethick0;
前高:=0 linethick; 前高POS:=0;
for i= PP downto lbound(MDNSP) do begin
i:=i-MDNSP[i]-1;
if M高[i]>A高 then begin
前高:=M高[i]; 前高POS:=i-M高SP[i];break;
end;
end;

C高: 前高;

由 cgjj 在 2019-04-15 15:16 發表:

引用:
最初由 picabu 發表
總版主您好,今天把上面的公式運用在操盤指標中的主圖加跌,發現以致茂(2360)為例會出現如附圖的"操盤指標數組下標越界或超出有效數據區間".看起來好像是找不到c高點.如果是這樣可以幫我修改成如果找不到C高點,就以前高=A高為高點,麻煩您
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
MUP:=CROSS(MACD,0); MUPSP:=BARSLAST(MUP);
MDN:=CROSS(0,MACD); MDNSP:=BARSLAST(MDN);
M高SP:=HHVBARS(H,MUPSP+1);
M高:=ref(H,M高SP);
if lbound(MDNSP)=0 then exit; //跳離
PP:=datacount-MDNSP[datacount]-1;
A高:=M高[PP] linethick0;
前高:=0 linethick; 前高POS:=0;
for i= PP downto lbound(MDNSP) do begin
i:=i-MDNSP[i]-1;
if M高[i]>A高 then begin
前高:=M高[i]; 前高POS:=i-M高SP[i];break;
end;
end;

C高: 前高;

原碼:DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
MUP:=CROSS(MACD,0); MUPSP:=BARSLAST(MUP);
MDN:=CROSS(0,MACD); MDNSP:=BARSLAST(MDN);
M高SP:=HHVBARS(H,MUPSP+1);
M高:=ref(H,M高SP);
if lbound(MDNSP)=0 then exit; //跳離
PP:=datacount-MDNSP[datacount]-1;
A高:M高[PP] linethick0;
前高:0 linethick; 前高POS:=0;
for i= PP downto lbound(MDNSP) do begin
  i:=i-MDNSP[i]-1; 
  if i<lbound(MUPSP) then begin
    前高:=A高; 前高POS:=PP-M高SP[PP];
    break;
  end;
  if M高[i]>A高 then begin
    前高:=M高[i]; 前高POS:=i-M高SP[i]; break;
  end;
end;
前高SP:barslast(barpos=前高POS) linethick;

由 picabu 在 2019-04-15 18:42 發表:

收到,謝謝總版大

全部時間均為台灣時間, 現在時間為01:37

在這個頁面顯示本主題全部的 11 個文章